FAQ

 Dipiscan/DipiLanAlert/WakeOnLan/WmiSysInfos

L'accès aux informations, le redémarrage, l'extinction, la fermeture de session, le verrouillage de session et la mise en veille prolongée d'une machine distante requièrent des droits. Mais attention, vous pouvez être administrateur sur la machine où vous avez ouvert votre session, cela ne vous permet pas pour autant de faire la pluie et le beau temps sur les autres machines : il faut que celles-ci reconnaissent votre compte comme étant admin...

Pour accéder à une machine appartenant à un "domaine" depuis votre poste appartenant au même domaine, cela ne posera pas de problème dès lors que votre compte est admin du domaine ou des machines concernées.

En revanche, pour accéder à une machine en "workgroup" depuis votre poste (que celui-ci soit également en "workgroup" ou dans un domaine), il faut que vous vous "présentiez" à la "cible" avec un compte/mot de passe reconnu par elle comme étant admin. Le plus simple est d'avoir créé un compte admin avec le même login/password sur toutes vos machines. Mais cela ne suffit pas car certains réglages natifs de Windows et de son pare-feu font barrière : administration à distance désactivée, accès WMI à distance soumis à l'UAC, pare-feu, etc...

Attention : le mot de passe ne doit pas être vide sinon cela ne fonctionnera pas à moins de devoir modifier un réglage dans les stratégies locales de sécurité.

Pour lever ces barrières, je vous propose un petit "script" que je lance systématiquement sur les machines auxquelles je veux pouvoir accéder à distance avec mes outils.

Attention, celui-ci n'est fonctionnel qu'à partir de Windows Vista (désolé pour ceux qui utilisent encore du XP). Et la configuration du firewall concerne le firewall intégré à Windows. Si vous l'avez remplacé par un logiciel tiers, il faudra adapter les règles.

Script à lancer "en tant qu'admin" sur les machines "cibles" (pas celle depuis laquelle vous opérez) :

conf_acces_a_distance.bat (télécharger)

@echo off
echo ### Vérification de l'exécution en tant qu'admin
net session >nul 2>&1
if %ERRORLEVEL% NEQ 0 (
    echo Echec.
    echo.
    echo /!\ Ce script doit être executé en tant qu'administrateur ! /!\
    goto fin
)
echo Ok.
echo.

echo ### Configuration du firewall pour activer la réponse au ping et la réponse aux requêtes NetBIOS
netsh advfirewall firewall add rule name="_ICMPv4" protocol=icmpv4:any,any dir=in action=allow
netsh advfirewall firewall add rule name="_NetBIOS UDP Port 137" dir=in action=allow protocol=UDP localport=137
netsh advfirewall firewall add rule name="_NetBIOS UDP Port 137" dir=out action=allow protocol=UDP localport=137
netsh advfirewall firewall add rule name="_NetBIOS UDP Port 138" dir=in action=allow protocol=UDP localport=138
netsh advfirewall firewall add rule name="_NetBIOS UDP Port 138" dir=out action=allow protocol=UDP localport=138
netsh advfirewall firewall add rule name="_NetBIOS TCP Port 139" dir=in action=allow protocol=TCP localport=139
netsh advfirewall firewall add rule name="_NetBIOS TCP Port 139" dir=out action=allow protocol=TCP localport=139
netsh advfirewall firewall add rule name="_NetBIOS TCP Port 445" dir=in action=allow protocol=TCP localport=445
netsh advfirewall firewall add rule name="_RPC" dir=in action=allow protocol=TCP localport=RPC
echo.

echo ### Activation de l'administration à distance
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Terminal Server" /v AllowRemoteRPC /t reg_dword /d 1 /f
echo.

echo ### Désactivation de l'UAC pour les appels distants
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System" /v LocalAccountTokenFilterPolicy /t reg_dword /d 1 /f

:fin
echo.
pause

Un redémarrage est généralement nécessaire pour que certains réglages soient appliqués. Après ceci vous ne devriez plus rencontrer de problème... du moins je l'espère.

Pour finir, après de longues recherches et de nombreux tests, il s'avère que l'accès WMI à distance est impossible sous WindowsXP Home : après retour d'expérience utilisateur, ce n'est pas visiblement pas le cas pour les éditions "Home/Familiale" des versions supérieures.

Date de création :21/12/2016 @ 11:25